; ARM assembly tutorial for Asmonite, example 11: the calling convention (Raspberry Pi Pico 2, Arm Cortex-M33).
; Adapted from the ARM-ASM-Tutorial by Niklas Guertler (examples BlinkFunctionCallingConvention 1 to 3);
; see LICENSE.txt.
;
; The rules of the AAPCS, the convention that compilers for Arm follow too:
;   - the first four arguments go in r0 .. r3, the result comes back in r0
;   - a function may change r0 .. r3 and r12 freely; the caller must not count on them
;   - r4 .. r11 must have their old value at the return: a function that uses them saves them on the
;     stack first ("push {r4, r5, lr}") and takes them back at the end ("pop {r4, r5, pc}")
;   - sp stays aligned to 8 bytes at a call (push and pop an even number of registers)
; blink(count in r0) calls delay(iterations in r0) and keeps its own values in r4 and r5 over the calls.
.target pico2
.arch thumb
.imagebase 0x20000000

RESETS_BASE         equ 0x40020000
RESETS_RESET_DONE   equ 0x08
RESET_BITS          equ (1 << 6) | (1 << 9)     ; IO_BANK0, PADS_BANK0
IO_BANK0_BASE       equ 0x40028000
GPIO25_CTRL         equ 0xcc
FUNCSEL_SIO         equ 5
PADS_BANK0_BASE     equ 0x40038000
PADS_GPIO25         equ 0x68
PAD_ISO             equ 1 << 8
SIO_BASE            equ 0xd0000000
SIO_GPIO_OUT_SET    equ 0x18
SIO_GPIO_OUT_CLR    equ 0x20
SIO_GPIO_OE_SET     equ 0x38
ALIAS_CLR           equ 0x3000
DELAY_COUNT         equ 1000000

_start:
    bl   setup_led
    movs r0, #5                 ; argument: 5 flashes
    bl   blink
    b    $

; ---- blink(r0 = number of flashes) ----
blink:
    push {r4, r5, r6, lr}       ; r4 .. r6 are ours now; 4 registers: sp stays aligned to 8
    mov  r4, r0                 ; r4 = flashes left (survives the calls of delay)
    ldr  r5, lit_sio
    ldr  r6, lit_led_bit
blink_loop:
    str  r6, [r5, #SIO_GPIO_OUT_SET]
    ldr  r0, lit_delay_value    ; argument of delay
    bl   delay                  ; may change r0 .. r3: nothing of ours is there
    str  r6, [r5, #SIO_GPIO_OUT_CLR]
    ldr  r0, lit_delay_value
    bl   delay
    subs r4, r4, #1
    bne  blink_loop
    pop  {r4, r5, r6, pc}       ; old r4 .. r6 back, return

; ---- delay(r0 = iterations) ----
delay:
    subs r0, r0, #1
    bne  delay
    bx   lr

; ---- IO_BANK0 and PADS_BANK0 out of reset, GPIO 25: SIO, output; changes r0 .. r2 ----
setup_led:
    ldr  r1, lit_resets_clr
    ldr  r0, lit_reset_bits
    str  r0, [r1]
    ldr  r1, lit_resets
setup_wait:
    ldr  r2, [r1, #RESETS_RESET_DONE]
    and  r2, r2, r0
    cmp  r2, r0
    bne  setup_wait
    ldr  r1, lit_pads_clr
    mov  r0, #PAD_ISO
    str  r0, [r1, #PADS_GPIO25]
    ldr  r1, lit_io_bank0
    movs r0, #FUNCSEL_SIO
    str  r0, [r1, #GPIO25_CTRL]
    ldr  r1, lit_sio
    ldr  r0, lit_led_bit
    str  r0, [r1, #SIO_GPIO_OE_SET]
    bx   lr

    align 4
lit_resets:      dd RESETS_BASE
lit_resets_clr:  dd RESETS_BASE + ALIAS_CLR
lit_reset_bits:  dd RESET_BITS
lit_pads_clr:    dd PADS_BANK0_BASE + ALIAS_CLR
lit_io_bank0:    dd IO_BANK0_BASE
lit_sio:         dd SIO_BASE
lit_led_bit:     dd 1 << 25
lit_delay_value: dd DELAY_COUNT