; ARM assembly tutorial for Asmonite, example 13: a table of bytes (Raspberry Pi Pico 2, Arm Cortex-M33).
; Adapted from the ARM-ASM-Tutorial by Niklas Guertler (example BlinkPattern2 and the sections on 8-bit
; values, alignment and arrays); see LICENSE.txt.
;
; The table holds bytes now: each one is a multiple of 500000 iterations, so 2 is short and 5 is long.
; "ldrb r0, [r7], #1" loads one byte from the address in r7 and then adds 1 to r7 (post-index): r7 walks
; through the table. The loop ends when r7 reaches blink_table_end. "mul" multiplies.
; After a table of bytes the next word must start at an address that is a multiple of 4: "align 4".
.target pico2
.arch thumb
.imagebase 0x20000000

RESETS_BASE         equ 0x40020000
RESETS_RESET_DONE   equ 0x08
RESET_BITS          equ (1 << 6) | (1 << 9)     ; IO_BANK0, PADS_BANK0
IO_BANK0_BASE       equ 0x40028000
GPIO25_CTRL         equ 0xcc
FUNCSEL_SIO         equ 5
PADS_BANK0_BASE     equ 0x40038000
PADS_GPIO25         equ 0x68
PAD_ISO             equ 1 << 8
SIO_BASE            equ 0xd0000000
SIO_GPIO_OUT_SET    equ 0x18
SIO_GPIO_OUT_CLR    equ 0x20
SIO_GPIO_OE_SET     equ 0x38
ALIAS_CLR           equ 0x3000
UNIT                equ 500000

_start:
    bl   setup_led
    bl   blink_pattern
    b    $

blink_pattern:
    push {r4, r5, r6, r7, r8, lr}
    ldr  r4, lit_sio
    ldr  r5, lit_led_bit
    ldr  r6, lit_unit
    adr  r7, blink_table
    adr  r8, blink_table_end
pattern_loop:
    str  r5, [r4, #SIO_GPIO_OUT_SET]
    ldrb r0, [r7], #1           ; the on time in units, r7 = r7 + 1
    mul  r0, r0, r6
    bl   delay
    str  r5, [r4, #SIO_GPIO_OUT_CLR]
    ldrb r0, [r7], #1           ; the off time
    mul  r0, r0, r6
    bl   delay
    cmp  r7, r8
    blo  pattern_loop
    pop  {r4, r5, r6, r7, r8, pc}

delay:
    subs r0, r0, #1
    bne  delay
    bx   lr

; ---- IO_BANK0 and PADS_BANK0 out of reset, GPIO 25: SIO, output; changes r0 .. r2 ----
setup_led:
    ldr  r1, lit_resets_clr
    ldr  r0, lit_reset_bits
    str  r0, [r1]
    ldr  r1, lit_resets
setup_wait:
    ldr  r2, [r1, #RESETS_RESET_DONE]
    and  r2, r2, r0
    cmp  r2, r0
    bne  setup_wait
    ldr  r1, lit_pads_clr
    mov  r0, #PAD_ISO
    str  r0, [r1, #PADS_GPIO25]
    ldr  r1, lit_io_bank0
    movs r0, #FUNCSEL_SIO
    str  r0, [r1, #GPIO25_CTRL]
    ldr  r1, lit_sio
    ldr  r0, lit_led_bit
    str  r0, [r1, #SIO_GPIO_OE_SET]
    bx   lr

    align 4
blink_table:
    db 2, 2, 2, 2, 2, 2
    db 5, 2, 5, 2, 5, 2
    db 2, 2, 2, 2, 2, 8
blink_table_end:
    align 4
lit_resets:      dd RESETS_BASE
lit_resets_clr:  dd RESETS_BASE + ALIAS_CLR
lit_reset_bits:  dd RESET_BITS
lit_pads_clr:    dd PADS_BANK0_BASE + ALIAS_CLR
lit_io_bank0:    dd IO_BANK0_BASE
lit_sio:         dd SIO_BASE
lit_led_bit:     dd 1 << 25
lit_unit:        dd UNIT